/* fig5_1.do

   Figure 5.1 (from example 5.1)

   (saves ROC plot coordinate data for subsequent graphics pkg import)

   programs required
       emroc.ado  (v 1.3.4 or later)

   data required: orchratio2.dta

   last update:  11 July 2005
*/
version 7
set more off
cap semt_profile
cap log close
************************

use g128 d using ${semt_data}orchratio2,clear
rename g128 y
la var y "gene 128"
compress
sort d y

log using ${semt_log}ex5_1,replace

* data for gene 128:

ta d

by d: l y

log off

emroc y d, gense(tpr) gensp(spec)

gen fpr = 1 - spec
gsort -y fpr tpr

qui log on

ta d
l y d fpr tpr

qui log off
sort fpr tpr
qui by fpr tpr: drop if _n>1
qui log on

* restricted to unique fpr,tpr pairs:

count

l fpr tpr

qui log off

* add record for origin (0,0)
gen byte expn = _n==1
expand 2 if expn
sort expn
by expn : replace fpr = 0 if expn==1 & _n==1
by expn : replace tpr = 0 if expn==1 & _n==1
sort fpr tpr

* save empirical ROC coordinate data

keep fpr tpr
order fpr tpr
sort fpr tpr
save ${semt_log}fig5_1,replace

log close